MEMO：Youtube の動画URLを取得する

サンプル

さっきのスクリプトを使用してさくっとサンプルを作ってみた。こちら。

package  
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.net.*;
    import flash.events.NetStatusEvent;
    import flash.events.SecurityErrorEvent;
    import flash.events.AsyncErrorEvent;
    
    public class Youtube extends Sprite
    {
        protected static const VIDEO_ID:String = "6kxDxLAjkO8"; // 動画ID
        protected static const CGI_PATH:String = "http://hogehoge.com/geturl.cgi"; // CGIのパス
        private var url:String;
        private var variables:URLVariables;
        private var video:Video;
        private var netStream:NetStream;
        private var netConnection:NetConnection;
        
        public function Youtube() 
        {
            connect();
        }

        private function connect():void {
            var request:URLRequest = new URLRequest( CGI_PATH + "?id=" + VIDEO_ID );
            request.method = URLRequestMethod.GET;
            var yLoader:URLLoader = new URLLoader();
            yLoader.dataFormat = URLLoaderDataFormat.TEXT;
            yLoader.addEventListener( Event.COMPLETE, loadCompleteHandler );
            yLoader.load( request );
        }
        
        private function loadCompleteHandler( e:Event ):void {
            url = e.target.data.toString();
            setVideo();
        }
        
        private function setVideo():void {
            video = new Video(320, 240);
            addChild(video);
            netConnection = new NetConnection();
            netConnection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            netConnection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            netConnection.connect(null);
        }
        
        private function netStatusHandler(evt:NetStatusEvent):void {
            if(evt.info.code == "NetConnection.Connect.Success") {
            	netStream = new NetStream(netConnection);
            	netStream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            	netStream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            	netStream.bufferTime = 5;
            	video.attachNetStream(netStream);
            	netStream.play( url );
            }
        }
        
        private function securityErrorHandler(evt:SecurityErrorEvent):void {
            trace(evt);
        }
        
        private function asyncErrorHandler(evt:AsyncErrorEvent):void {
            trace(evt);
        }
    }
}

まとめ

今のところこの方法で運用して4〜５ヶ月問題は無いけど、Youtube の仕様が変更された場合にいちいち修正が発生するので通常の案件では使えないかもしれない。Youtube から API が正式に提供されない限り、どうやっても邪道な手段をとる以外にないんだけど、確実で安定した方法っていうは無いんだろうか。